app-i18n/ibus-anthy: Update python compat

app-i18n/ibus-anthy/Manifest

@@ -0,0 +1 @@
+DIST ibus-anthy-1.5.17.tar.gz 292242 BLAKE2B 5dd5fd5d10a7ee239e2f40bb4f31469f2fd024fdd5c3afc2d1ab6f8df54b23dc8b4c3494889ebdf4924e54a0ea61e92dbb109db3cf02628ceb3a9d4e5ce084e0 SHA512 c361452af73ef49278142e3eb63e7697bb6f4369fd26fdc94405aa976cb5b3a323cb67f31099d348cf3495160a1259b56c941cfb0facce1d3c050daa5264b3d2

app-i18n/ibus-anthy/ibus-anthy-1.5.17.ebuild

@@ -0,0 +1,73 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit autotools gnome2-utils python-single-r1 xdg
+
+DESCRIPTION="Japanese Anthy engine for IBus"
+HOMEPAGE="https://github.com/ibus/ibus/wiki"
+SRC_URI="https://github.com/ibus/${PN}/archive/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64"
+IUSE="nls"
+RESTRICT="mirror"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	app-i18n/anthy
+	$(python_gen_cond_dep '
+		app-i18n/ibus[python(+),${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	')
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}"
+BDEPEND="sys-devel/gettext
+	virtual/pkgconfig"
+
+src_prepare() {
+	default
+	eautoreconf
+	gnome2_environment_reset
+}
+
+src_configure() {
+	econf \
+		$(use_enable nls) \
+		--enable-private-png \
+		--with-layout=default \
+		--with-python=${EPYTHON}
+}
+
+src_test() {
+	:
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+
+	python_optimize
+}
+
+pkg_preinst() {
+	xdg_pkg_preinst
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+
+	if ! has_version app-dicts/kasumi; then
+		elog "app-dicts/kasumi is not required but probably useful for you."
+	fi
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}

app-i18n/ibus-anthy/metadata.xml

@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>tenno@suij.in</email>
+		<name>Enno Tensing</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">ibus/ibus-anthy</remote-id>
+	</upstream>
+</pkgmetadata>